home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / NEW / J-Jim Butterfield / (n)j2.d64 / arrow (.txt) < prev    next >
Commodore BASIC  |  2007-02-24  |  2KB  |  57 lines
  1. 100 PRINT"[147] ARROW [146]    JIM BUTTERFIELD"
  2. 105 REM RECUT FOR C64 MARCH 87
  3. 110 INPUT"INSTRUCTIONS";Z$:IFASC(Z$)=78GOTO190
  4. 120 PRINT"GUIDE THE MOVING 'SNAKE' WITH KEYS:"
  5. 130 PRINT" B(DOWN), F(LEFT), H(RIGHT), T(UP)"
  6. 140 PRINT"DON'T HIT THE BOUNDARY (OR YOURSELF);"
  7. 150 PRINT"..TRY TO HIT THE BOXES FOR POINTS."
  8. 160 PRINT"YOU HAVE 60 SECONDS OF PLAY. GOOD LUCK!"
  9. 170 PRINT"     HIT ANY KEY TO START"
  10. 180 GETZ$:IFZ$=""GOTO180
  11. 190 DIMP(255),K(255),D(3),V(8),H(8),T(8),R(8):K=.1:L=RND(0)
  12. 195 K(84)=4:K(66)=1:K(70)=2:K(72)=3
  13. 200 D(0)=22:D(1)=60:D(2)=62:D(3)=30
  14. 210 T9=1024:T6=3599:PRINT CHR$(14);
  15. 220 M1=54276:M2=59466:M3=54273:POKEM1,16:POKE54278,240:POKE54296,15
  16. 230 PRINT"[142][147]   SCORE: 0":PRINT"(PLEASE WAIT)"
  17. 235 L=PEEK(646):FOR J=55296 TO 56319:POKE J,L:NEXT J
  18. 240 L=40
  19. 250 FORJ=T9+LTOT9+2*L-1:POKEJ,81:POKEJ+23*L,81:NEXTJ
  20. 260 FORJ=T9+2*LTOT9+24*LSTEPL:POKEJ,81:POKEJ+L-1,81:NEXT
  21. 270 V=5:H=5:V1=0:H1=1:P2=10:D1=2
  22. 280 TI$="000000"
  23. 290 PRINT"";RIGHT$(TI$,2):IFTI>T6GOTO620
  24. 300 GETZ$:IFZ$=""GOTO330
  25. 301 Z=K(ASC(Z$))-1:IFZ<0GOTO330
  26. 320 D1=Z:D=Z-1.5:V1=INT(ABS(D))*SGN(D):H1=SGN(D)-V1
  27. 330 V=V-V1:H=H+H1:P=T9+V*L+H
  28. 350 P9=PEEK(P):POKEM1,17:POKEM3,29-D1*4:POKEM2,15
  29. 360 R6=R7:R7=R7+1:IFR7>P2THENR7=0
  30. 370 P1=P(R7):P(R7)=P:POKEM1,16:IFP1<>0THENPOKEP1,32
  31. 380 POKEP,D(D1):P1=P(R6):IFP1<>0THENPOKEP1,81
  32. 390 IFP9<>32GOTO540
  33. 400 IFRND(1)>KGOTO290
  34. 410 V%=RND(1)*L/10:P9=86+V%:V9=V(V%):IFV9>0GOTO591
  35. 470 V2=INT(RND(1)*20)+3:H2=INT(RND(1)*(L-4))+2
  36. 480 FORV3=V2-1TOV2+1:P3=V3*L+T9:FORH3=H2-1TOH2+1:IFPEEK(P3+H3)<>32GOTO470
  37. 490 NEXTH3,V3:V(V%)=V2:H(V%)=H2
  38. 500 FORV3=V2-1TOV2+1:P3=V3*L+T9:FORH3=H2-1TOH2+1
  39. 510 POKEM1,17:POKEM2,15:POKEM3,30
  40. 520 POKEP3+H3,P9:POKEM1,16
  41. 530 NEXTH3,V3:T=9*RND(1):P8=V2*L+H2+T9:POKEP8,49+T:T(V%)=T:R(V%)=P8:GOTO290
  42. 540 V%=P9-86:IFV%<0GOTO600
  43. 550 P8=R(V%):T=T(V%):P2=P2+T:T$=TI$
  44. 560 T=T-1:S=S+1:POKEP8,T+49:POKEM1,17:POKEM2,15
  45. 570 PRINT"";S
  46. 580 FORJ=30TO100STEP 1:POKEM3,J:NEXT:POKEM1,16:IFT>=0GOTO560
  47. 590 P2=P2+1:TI$=T$:V9=V(V%)
  48. 591 FORV3=V9-1TOV9+1:P3=V3*L+T9:H9=H(V%)+P3:FORH3=H9-1TOH9+1
  49. 594 POKEH3,32:NEXTH3,V3:V(V%)=0:POKER(V%),32:GOTO290
  50. 600 POKEM1,17:POKEM2,15:POKEM3,40:FORJ=1TO1000:NEXT:POKEM1,16
  51. 610 POKE54296,0
  52. 620 PRINT"ANOTHER GAME?[146]   [157][157][157]";
  53. 630 GETZ$:IFZ$=""GOTO630
  54. 640 IFZ$="Y"THENCLR:GOTO190
  55. 650 IFZ$<>"N"GOTO630
  56. 660 PRINT"[147]";
  57.